汇编语言实验17中断实现通过逻辑扇区号对软盘进行读写

编号的方法如下所示:

物理扇区号      逻辑扇区号
0面0道1扇区       0
0面0道2扇区       1
0面0道3扇区       2
0面0道4扇区       3
.
.

0面0道18扇区    17
0面1道1扇区     18
0面1道2扇区     19
0面I道3扇区     20
0面1道4扇区     21
.
.

0面1道18扇区    35
0面1道1扇区     36
0面1道2扇区     37
0面I道3扇区     38
0面1道4扇区     39
.
.

0面79道18扇区   1439
1面0道1扇区     1440
1面0道2扇区     1441
1面0道3扇区     1442
1面0道4扇区     1443

可以看出,逻辑扇区号和物理扇区号的关系如下:
逻辑扇区号=(面号*80 +磁道号)*18+扇区号11
那么如何根据逻辑扇区号算出物理编号呢?可以用下面的算法。
int():描述性运算符,取商
rem():描述性运算符,取余数

逻辑扇区号=(面号*80 +磁道)* 18+扇区号-1
面号=int(逻辑扇区号/1440)
磁道号=int(rem(逻辑扇区号/1440)/ 18)
扇区号=rem(rem(逻辑扇区号/1440)/18)+ 1
安装一个新的int 7ch中断例程,实现通过逻辑扇区号对软盘进行读写。
参数说明:
(1)用ah寄存器传递功能号:0表示读,1表示写;
(2)用dx寄存器传递要读写的扇区的逻辑扇区号;
(3)用。s:bx指向存储读出数据或写入数据的内存区。
提示,用逻辑扇区号计算出面号、磁道号、扇区号后,调用int 13h中断例程进行实际的读写。
测试程序 文件 test.asm
写扇区:将显存的内容写入软盘A的某一个扇区之中
读扇区:将软盘A的某一个扇区中的数据读到某一段开辟的内存空间

assume cs:code
stack segment
    db 550 dup(0)       
stack ends
code segment
start:
        mov ax,stack
        mov ss,ax
        mov sp,550
        
        ; write floppy
        mov ah,1    
        mov dx,20   
        
        mov bx,0B800H
        mov es,bx
        mov bx,0
        
        int 7ch
        
        ; read floppy to memory
        mov ah,0
        mov dx,20
        
        mov bx,stack
        mov es,bx
        mov bx,0000
        
        int 7ch
        
        mov ax,4c00H
        int 21H
    
code ends
end start

int 7CH 中断例程安装程序 文件 setup.asm
功能: 将 新的int7CH中断例程安装到内存0000:0200H 开始

assume cs:code
code segment
    start:  ;------ 安装功能程序到 0000:0200H 开始 --------
            mov ax,cs
            mov ds,ax
            mov si, offset rw
            
            mov ax,0
            mov es,ax
            mov di,200H
            mov cx,offset rwend - offset rw
            cld
            rep movsb

            ;------ 在中断向量表 7Ch号表项处写入 
            ;       中断处理程序的入口地址0000:0200h -----
            mov ax,0
            mov es,ax
            mov word ptr es:[7CH*4],200H
            mov word ptr es:[7CH*4+2],0
            
            
            mov ax,4c00H
            int 21H
            
    ;---------- 7CH号中断处理程序本身 ---------     
            
    rw:         push ax
                
                mov ax,dx
                mov dx,0
                mov cx,05a0H
                div cx
                push ax
                
                mov ax,dx
                mov dx,0
                mov cx,0012H
                div cx
                push ax
                
                add dx,1
                mov cl,dl
                
                pop ax
                mov ch,al
                
                pop dx
                mov dh,dl
                
                mov dl,0
                
                pop ax
                add ah,2
                
                mov al,1
        
                int 13H
                
            iret
    rwend:  nop

    
    code ends
    end start

发布日期:

所属分类: 易语言 标签: