易语言教程数组加入成员

文章目录[隐藏]

官方源码:

调用格式: 〈无返回值〉 加入成员 (通用型变量数组 欲加入成员的数组变量,通用型数组/非数组 欲加入的成员数据) - 系统核心支持库->数组操作
英文名称:AddElement
将数据加入到指定数组变量的尾部,并通过重新定义数组维数自动增加其成员数目。数组变量如为多维数组,加入完毕后将被转换为单维数组。本命令为初级命令。
参数<1>的名称为“欲加入成员的数组变量”,类型为“通用型(all)”,提供参数数据时只能提供变量数组。
参数<2>的名称为“欲加入的成员数据”,类型为“通用型(all)”,提供参数数据时可以同时提供数组或非数组数据。参数值所指定成员数据的数据类型必须能够与第一个参数所指定的数组变量相匹配。

操作系统需求: Windows、Linux、Unix

教程源码:

.版本 2
.支持库 spec

.程序集 窗口程序集_启动窗口
.程序集变量 数组变量, 文本型, , "0"

.子程序 __启动窗口_创建完毕

.子程序 _按钮1_被单击, , , 加入成员-1
.局部变量 数组1, 文本型, , "1"

' 将数据加入到指定数组变量的尾部,并通过重新定义数组维数自动增加其成员数目。数组变量如为多维数组,加入完毕后将被转换为单维数组。本命令为初级命令。
数组1 [1] = “易”
调试输出 (数组1)
加入成员 (数组1, “语”)
调试输出 (数组1)
加入成员 (数组1, “言”)
调试输出 (数组1)

.子程序 _按钮2_被单击, , , 加入成员-2
.局部变量 文本, 文本型, , "0"
.局部变量 数组文本, 文本型, , "0"
.局部变量 n, 整数型

文本 = 分割文本 (编辑框1.内容, #换行符, )
.计次循环首 (取数组成员数 (文本), n)
.如果真 (文本 [n] ≠ “”)
加入成员 (数组文本, 文本 [n])
.如果真结束

.计次循环尾 ()
调试输出 (数组文本)

.子程序 _按钮3_被单击, , , 加入成员-3
.局部变量 文本, 文本型
.局部变量 文本数组, 文本型, 静态, "0"

置随机数种子 ()
文本 = 多项选择 (取随机数 (1, 9), “1”, “”, “2”, “”, “3”, “”, “4”, “”, “5”)
.如果真 (文本 ≠ “”)
加入成员 (文本数组, 文本)
调试输出 (文本数组)
.如果真结束

.子程序 _按钮4_被单击, , , 加入成员-3
.局部变量 数组A, 整数型, , "0"
.局部变量 数组B, 整数型, , "0"
.局部变量 m, 整数型
.局部变量 i, 整数型

数组A = { 1, 3, 5, 7, 9 }
.计次循环首 (取数组成员数 (数组A), m)
加入成员 (数组B, 数组A [m])
加入成员 (数组B, 数组A [m] + 1)
.计次循环尾 ()
调试输出 (数组B)
.计次循环首 (取数组成员数 (数组B), i)
编辑框1.加入文本 (到文本 (数组B [i]) + #换行符)
.计次循环尾 ()

.子程序 _按钮5_被单击, , , 加入成员-5
.局部变量 a, 文本型, , "0"
.局部变量 b, 文本型, , "0"
.局部变量 i, 整数型

a = { “1”, “2”, “3”, “4”, “5” }
' b = a
' 调试输出 (b)
' 复制数组 (b, a)
' 调试输出 (b)
' ---------------加入成员
.计次循环首 (取数组成员数 (a), i)
加入成员 (b, a [i])
.计次循环尾 ()
调试输出 (b)

.子程序 _按钮6_被单击, , , 加入成员-6
.局部变量 n, 整数型

加入成员 (数组变量, “我是第” + 到文本 (取数组成员数 (数组变量) + 1) + “个成员”)
编辑框1.内容 = “数组成员数当前是: ” + 到文本 (取数组成员数 (数组变量)) + “个”
.计次循环首 (取数组成员数 (数组变量), n)
编辑框1.内容 = 编辑框1.内容 + #换行符 + “数组的第” + 到文本 (n) + “个成员的值 ” + 数组变量 [n]
.计次循环尾 ()


发布日期:

所属分类: 易语言 标签: